* /* MACCOMP Y-2 SC1D0/SJD48                                         */ 00010003
* /* MACSTAT Y-2 73078/021160                                        */ 00012003
         MACRO                                                          00020000
&NAME    WRITE &DECB,&TYPE,&DCB,&ADDR,&LENGTH,&KEY,&RCDREF,&MF=I,      *00040003
               &RPL=,&ACB=,&AREA=,&AREALEN=,&RECLEN=,&AAREA=,    Y02072*00050003
               &AAREALN=,&ARECLEN=,&ECB=,&EXIT=,                 Y02072*00052003
               &OPTCD=,&ARG=,&BRANCH=                           ZM30024 00056003
         GBLB  &IHBWR,&IHBT(2),&IHBS(4)                                 00060000
         LCLB  &ERR(2)                                                  00064019
         AIF   ('&RPL' NE '').VTAM      ISSUE VTAM WRITE         Y02072 00066003
&ERR(1)  SETB  ('&DECB' EQ '')                                          00068019
&ERR(2)  SETB  ('&TYPE' EQ '')                                          00072019
         AIF   (&ERR(2)).E0                                             00076019
&IHBS(1) SETB  (K'&TYPE EQ 1)                                           00080000
&IHBS(2) SETB  (K'&TYPE EQ 2)                                           00100000
&IHBS(3) SETB  (K'&TYPE EQ 3)                                           00120000
&IHBS(4) SETB  (K'&TYPE EQ 4)                                           00140000
&IHBWR   SETB  1                                                        00160000
&IHBT(1) SETB  (T'&LENGTH EQ 'N')                                       00180000
&IHBT(2) SETB  (T'&RCDREF EQ 'N')                                       00200000
         AIF   ('&TYPE'(1,1) EQ 'S').BSAMR                              00260000
         AIF   ('&TYPE'(1,1) EQ 'K').BISAMR                             00280000
         AIF   ('&TYPE'(1,1) EQ 'D').BDAMR                              00300000
         AIF   ('&TYPE'(1,1) EQ 'T').BTAMR                              00320000
         IHBERMAC 63,,&TYPE             TYPE INVALID                    00340019
         AGO   .E0                                                      00360019
.BSAMR   AIF   (&ERR(1)).E0                                             00380019
&NAME    IHBRDWRS &DECB,&TYPE,&DCB,&ADDR,&LENGTH,&KEY,&RCDREF,MF=&MF    00400003
         MEXIT                                                          00420000
.BISAMR  AIF   (&ERR(1)).E0                                             00440019
&NAME    IHBRDWRK &DECB,&TYPE,&DCB,&ADDR,&LENGTH,&KEY,&RCDREF,MF=&MF    00460003
         MEXIT                                                          00480000
.BTAMR   AIF   (&ERR(1)).E0                                             00500019
&NAME    IHBRDWRT &DECB,&TYPE,&DCB,&ADDR,&LENGTH,&KEY,&RCDREF,MF=&MF    00520003
         MEXIT                                                          00540000
.BDAMR   AIF   (&ERR(1)).E0                                             00560019
&NAME    IHBRDWRD &DECB,&TYPE,&DCB,&ADDR,&LENGTH,&KEY,&RCDREF,MF=&MF    00580003
         MEXIT                                                          00600000
.VTAM    ANOP                                                    Y02072 00650003
&IHBWR   SETB  1                      SET FOR ALL WRITES         Y02072 00700003
&NAME    IHBRDWRA ACB=&ACB,AREA=&AREA,AREALEN=&AREALEN,          Y02072*00800003
               RECLEN=&RECLEN,AAREA=&AAREA,AAREALN=&AAREALN,     Y02072*00850003
               ARECLEN=&ARECLEN,ECB=&ECB,EXIT=&EXIT,ARG=&ARG,    Y02072*00900003
               OPTCD=&OPTCD,                                     Y02072*00950003
               IHBRW=X'11',RPL=&RPL,BRANCH=&BRANCH              ZM30024 01000003
         MEXIT                                                   Y02072 01050003
.E0      AIF   (NOT &ERR(1)).E1                                         10600019
         IHBERMAC 07                    &DECB MISSING                   20600019
.E1      AIF   (NOT &ERR(2)).MEND                                       30600019
         IHBERMAC 25                    &TYPE MISSING                   40600019
.MEND    MEND                                                           50600019