* /* MACCOMP Z-4 SC1CX/PKD16                                         */ 00050040
* /* MACSTAT Z-4 75007/Z40BPSS                                       */ 00080040
         MACRO                                                          00150040
&LABEL   TSEVENT   &EVENT,&ASID=,&ASIDL=,&ENTRY=SVC                     00200040
         LCLA      &EVENTO                                              00250040
* /* MACDATE Y-2 73257                                               */ 00300040
&EVENTO  SETA      0                                                    00350040
         AIF   ('&EVENT'EQ'PPMODE').EOK                                 00400040
&EVENTO  SETA      50                                                   00450040
         AGO       .ERROR1                                              00500040
.EOK     AIF       ('&ASID'NE''AND'&ASIDL'NE'').ERROR4                  00550040
         AIF       ('&ASID'EQ'').NULREG                                 00600040
         AIF       ('&ASID'(1,1)NE'(').ERROR2                           00650040
         AIF       ('&ASID'EQ'(0)').SKPREG                              00700040
&LABEL   LR    0,&ASID(1)              PUT ASID INTO REGISTER 0         00750040
         AGO       .SHFTID                                              00800040
.NULREG  AIF       ('&ASIDL'EQ'').OKLAB                                 00850040
         AIF       ('&ASIDL'(1,1)EQ'(').ERROR3                          00900040
         AIF       ('&ASIDL'(K'&ASIDL,1)NE')').OKLAB                    00950040
&LABEL   LH    0,&ASIDL                PUT ASID INTO REGISTER 0         01000040
         AGO       .SHFTID                                              01050040
.OKLAB   ANOP                                                           01100040
&LABEL   LA    0,&EVENTO.(0,0)         TSEVENT CODE                     01150040
         AIF       ('&ASIDL'EQ'').OKID                                  01200040
         ICM   0,12,&ASIDL             PUT ASID INTO REGISTER 0         01250040
         AGO       .OKID                                                01300040
.SKPREG  AIF       ('&LABEL'EQ'').SHFTID                                01350040
&LABEL   DS    0H                                                       01400040
.SHFTID  SLL   0,16(0)                 SHIFT INTO PROPER POSITION       01450040
         AIF       (&EVENTO EQ 0).OKID                                  01500040
         AIF       ('&ENTRY'NE'BRANCH').IC                              01550040
         LA    14,&EVENTO.(0,0)        TSEVENT CODE                     01600040
         OR    0,14                    PUT CODE INTO REGISTER 0         01650040
         AGO       .OKID                                                01700040
.IC      IC    0,IRAC&SYSNDX+1         PUT CODE INTO REGISTER 0         01750040
         B     IRAB&SYSNDX             BRANCH AROUND CONSTANT           01800040
IRAC&SYSNDX DC AL2(&EVENTO)            TSEVENT CODE                     01850040
IRAB&SYSNDX EQU *                                                       01900040
.OKID    AIF       ('&ENTRY'EQ'BRANCH').BR                              01950040
         AIF       ('&ENTRY'NE'SVC').ERROR5                             02000040
.SVC     SVC   95                      SYSTEM RESOURCES MANAGER SVC     02050040
         MEXIT                                                          02100040
.BR      ANOP                                                           02150040
         L     15,CVTPTR(,0)           SYSTEM CVT ADDRESS               02200040
         L     15,CVTOPTE-CVT(,15)     SYSTEM RESOURCES MANAGER ENTRY   02250040
         BALR  14,15                   INVOKE SYSTEM RESOURCES MANAGER  02300040
         MEXIT                                                          02350040
.ERROR1  MNOTE     4,'***  IRA001  INVALID TSEVENT MNEMONIC NAME OPERANX02400040
               D -                 &EVENT  ***'                         02450040
         MNOTE     *,'             -PPMODE- IS THE ONLY MNEMONIC SUPPORX02500040
               TED                 IN THE CURRENT RELEASE OF OS/VS2'    02550040
         MEXIT                                                          02600040
.ERROR2  MNOTE     8,'***  IRA002  INVALID ASID OPERAND SPECIFICATION -X02650040
                                   &ASID  ***'                          02700040
         MNOTE     *,'             USE ASIDL KEYWORD WHEN THE ASID VALUX02750040
               E                   IS NOT CONTAINED IN A REGISTER'      02800040
         MEXIT                                                          02850040
.ERROR3  MNOTE     8,'***  IRA003  INVALID ASIDL OPERAND SPECIFICATION X02900040
               -                   &ASIDL  ***'                         02950040
         MNOTE     *,'             USE ASID KEYWORD IF THE ASID VALUE IX03000040
               S                   PROVIDED IN A REGISTER'              03050040
         MEXIT                                                          03100040
.ERROR4  MNOTE     8,'***  IRA004  ASID AND ASIDL PARAMETERS ARE       X03150040
                                   MUTUALLY EXCLUSIVE  ***'             03200040
         MEXIT                                                          03250040
.ERROR5  MNOTE     4,'***  IRA005  INVALID ENTRY TYPE - SVC ASSUMED  **X03300040
               *'                                                       03350040
         AGO       .SVC                                                 03400040
         MEND                                                           03450040